#pragma rtGlobals=1		// Use modern global access method.
#include "specMore"
#include "spec"

Menu "Macros"
	"Squeeze multiple laserscans",SqueezeHorizOffsets(NaN)
End


Function SqueezeHorizOffsets(timeSpace)
	Variable timeSpace=10

	if (timeSpace<0 || numtype(timeSpace))
		timeSpace = 10
		Prompt timeSpace, "time between each laserscan (sec)"
		DoPrompt "give time",timeSpace
		if (V_flag)
			return Nan
		endif
	endif

	String traceList = TraceNameList("",";",1)
	Variable N = ItemsInList(traceList)
	Variable i,j
	String traceNameStr

	Make/N=(N)/O timeStarts__,timeEnds__
	timeStarts__ = NaN
	timeEnds__ = NaN

	// first loop through the speculars to fill list of starting times
	for (i=0,j=0;i<N;i+=1)
		traceNameStr = StringFromList(i,traceList)
		if (strsearch(traceNameStr,"specular",0))				// to find list of start, only use speculars
			continue
		endif

		Wave xwave = XWaveRefFromTrace("",traceNameStr)
		timeStarts__[j] = xwave[0]
		timeEnds__[j] = xwave[inf]
		j += 1
	endfor
	Redimension /N=(j) timeStarts__,timeEnds__
	Sort timeStarts__ timeStarts__,timeEnds__
	Make/N=(j)/O offsets__
	offsets__ = NaN

	// second compute offsets from times
	offsets__[0] = 0
	for (i=1;i<j;i+=1)
		offsets__[i] = round(timeEnds__[i-1]-timeStarts__[i] + offsets__[i-1] + timeSpace)
	endfor

	// third apply the offsets to the waves
	for (i=0;i<N;i+=1)
		traceNameStr = StringFromList(i,traceList)
		if (strsearch(traceNameStr,"specular",0) && strsearch(traceNameStr,"offspec",0))
			continue
		endif
		Wave xwave = XWaveRefFromTrace("",traceNameStr)
		j = round(BinarySearchInterp(timestarts__,xwave[0]))
		ModifyGraph offset($traceNameStr)={offsets__[j],0}
	endfor
	KillWaves/Z timeStarts__,timeEnds__,offsets__
End




Proc Fix_LoadLaserScan(scanNum,fileName,path,overlay)
	// fixes up a laser scan, reads it in if necessary
	Variable scanNum=-1				// spec scan number
	Prompt scanNum, "scan number (if < 0, you will get a list choices)"
	String fileName=StrVarOrDefault("root:specDefaultFile","")
	String path=StrVarOrDefault("root:specDefaultPath","raw")
	Prompt path, "path for raw data", popup, PathList("*", ";", "")
	String overlay="new"
	Prompt overlay, "new plot", popup "new;append;"
	Silent 1

	String fldrSav= GetDataFolder(1)
	if (scanNum<1)
		String/G temp__list_ = GetListOfLaserscans(fileName,path)
		ChooseScanNum()
		scanNum = str2num(temp__list_)
		KillStrings/Z temp__list_
		fileName =  root:specDefaultFile
		path = root:specDefaultPath
	endif

	String folderName = ":spec"+num2istr(scanNum)

	if (!DataFolderExists(folderName))			// no data, read it in
			Variable/G root:extraProcess
			Variable extraOld = root:extraProcess
			root:extraProcess = 0				// do not defalut normalization for laser scans
			specRead(fileName,scanNum,path)
			root:extraProcess = extraOld		// restore default normalization
	endif
	if (!DataFolderExists(folderName))			// data alredy read in, remove it and read again
		DoAlert 0, "data folder '"+folderName+"', not found"
		return
	endif
	SetDataFolder folderName
	if (numpnts(Io)<1)							// no data, so stop here
		SetDataFolder fldrSav
		DoAlert 0, "Aborting, scan found, but zero length data"
		return
	endif

	if ((exists("specular")==1) %| (exists("sig")==1))						// already done, repeat?
		DoAlert 1, "remake normalized waves?"
		if (V_Flag!=1)
			SetDataFolder fldrSav
			DoAlert 0, "Aborting"
			return
		endif
	endif
	Variable filterTrans=(specInfo(scanNum,"filterTrans")
	filterTrans = numtype(filterTrans) ? 1 : filterTrans
	if (cmpstr("append",overlay))					// a new graph, create the graph window
		Display
	endif

	// if binned, put binning into wave note
//	if (SVAR_Exists(specComment))
	if (exists("specComment")==2)
//		SVAR comment=:specComment
		Variable i = strsearch(specComment,"binned by ",0)
		if (i>=0)									// binning is present
			Variable binning=str2num(specComment[i+9,i+20])
			if (binning>1)
				String binStr="binning="+num2istr(binning)+";"
				prependNote(Io,binStr)
				prependNote(Time_,binStr)
				prependNote(Det_bot,binStr)
				if (exists("Det_top")==1)						// a dual detector scan
					prependNote(Det_top,binStr)
				endif
			endif
		endif
	endif

	if (exists("Det_top")==1)						// a dual detector scan
		duplicate/O Io specular,offspec
		specular = Det_bot / Io / filterTrans
		offspec = Det_top / Io / filterTrans
		AppendToGraph specular vs Time_
		AppendToGraph offspec vs Time_
	else
		duplicate/O Io sig
		sig = Det_bot / Io / filterTrans
		AppendToGraph sig vs Time_
	endif
	LaserStyle_()
	SetScale d 0,0,"sec", Time_
	SetDataFolder fldrSav
EndMacro
Proc ChooseScanNum(scanNum)
	Variable scanNum
	Prompt scanNum,"laserscan number", popup, :temp__list_
	Silent 1
	:temp__list_  = StringFromList(scanNum-1, :temp__list_ )
EndMacro
Function prependNote(wav,nStr)	// prepend a string to a wave note, just return is additional part is empty
	Wave wav				// wave
	String nStr				// string to prepend to wave note
	if (strlen(nStr)<1)
		return 1
	endif
	String noteStr=note(wav)			// save current wavenote
	Note/K wav							// clear wavenote
	Note wav nStr+noteStr
End

Function/T GetListOfLaserscans(fileName,path)
		// get scan number for laserscans in a spec file
	String fileName
	String path

	Variable fileVar			// file ref number
	Variable i,j
	Variable V_flag
	String scanList="",posList

	Open /R/P=$path/M="spec data file"/Z fileVar as fileName
	if (V_flag)
		Open /R/M="spec data file" fileVar as fileName
	endif
	FStatus(fileVar)
	if (exists("root:specDefaultFile")!=2)
		String /G root:specDefaultFile
	endif
	String/G root:specDefaultFile = S_fileName

	if (exists("root:specDefaultPath")!=2)
		String /G root:specDefaultPath
	endif
	String/G root:specDefaultPath = path

	posList = ListPosOfLineTypes(fileVar," laserscan ")
	if (strlen(posList)<1)
		return ""
	endif

	String line=" "
	line = PadString(line, 80, 0)
	i = 0
	Variable N=ItemsInList(posList)
	do
		FSetPos fileVar, str2num(StringFromList(i, posList))-20
		FBinRead fileVar, line
		j = strsearch(line, "#S ", 0)+2
		if (j>=0)
			scanList += num2istr(str2num(line[j,j+10]))+";"
		endif
		i += 1
	while(i<N)
	Close fileVar
	return scanList
End



Proc extraSpecUserReadProcess()
	if (stringmatch(:specCommand,"*slewscan*") && exists("Det_bot"))
			:specYwave = "Det_bot"
	endif
EndMacro



Proc LaserStyle_() : GraphStyle
	PauseUpdate; Silent 1		// modifying window...

//	Modify gfSize=18				// these lines from 	JonsStyle_()
	Modify/Z tick=2, minor=1, standoff=0
	ModifyGraph lowTrip=0.001
	Modify/Z mirror(bottom)=1
	Modify/Z mirror(left)=1
	ModifyGraph/Z rgb[0]=(0,0,62000)
	Variable i=0
	String wname, wlist
	wlist = TraceNameList("", ";", 1)
	do
		wname = StringFromList(i, wlist)
		if (stringmatch(wname,"specular*"))
			ModifyGraph/Z rgb($wname)=(0,0,62000)
		endif
		if (stringmatch(wname,"offspec*"))
			ModifyGraph/Z rgb($wname)=(65535,0,0)
		endif
		i += 1
	while(strlen(wname)>0)

	Label left "detector / I\\Bo\\M";DelayUpdate
	Label bottom "time  (\\U)"
	SetAxis/A/E=1 left

	String str=GetDataFolder(0)
	Variable scanNum=0
	if (!cmpstr("spec",str[0,3]))							// can decode scan number from current folder
		scanNum = str2num(str[4,inf])
	endif

	String textStr = ""										//	String textStr = "Escete ?,  "
	if (exists("specComment2")==2)
		textStr += specComment2+"\r"
	endif
	if (exists("specComment1")==2)
		textStr += specComment1+"\r"
	endif
	if (exists("specComment")==2)
		textStr += specComment+"\r"
	endif

	textStr += "\\Z12"
	if (exists("timeWritten")==2)
		textStr += timeWritten
	else
		if (exists("specCommand")==2)
			i = strsearch(specCommand," #D ",0)
			if (i>0)
				if (char2num(specCommand[i+3])==32)		// remove any leading space
					i += 1
				endif
				textStr += specCommand[i+3,inf]
			else
				textStr += specCommand
			endif
		endif
	endif
	if (scanNum>0)
		textStr += ",  #"+num2istr(scanNum)
	endif
	textStr += "\\M\r"

	Variable temp = specInfo(scanNum,"temperature")
	if (!numtype(temp) && temp>0)
		textStr += "T\\BTC\\M = "+num2str(temp)+"¡ C"
	else
		textStr += "T\\BTC\\M = ???¡ C"
	endif
	textStr += ",  "

	temp = GetTxray()
	if (!numtype(temp) && temp>0)
		textStr += "T\\Bx-ray\\M = "+num2str(temp)+"¡ C"
	else
		textStr += "T\\Bx-ray\\M = ???¡ C"
	endif

	str = StringByKey("DATAFILE", note($StringFromList(0, wlist)),"=")
	if (strlen(str)>0)
		textStr = textStr +"\r\\Z12file = "+str+"\\M"
	endif

	Textbox/C/N=text0/F=0/S=3 textStr
EndMacro


Function GetTxray()
	Variable Txray = NumVarOrDefault("root:Packages:spec:Txray",NaN)
	Prompt Txray, "the X-ray temperature (C)"
	DoPrompt "choose Temperature", Txray
	if (!numtype(Txray))
		Variable/G root:Packages:spec:Txray=Txray
	endif
	return Txray
End